@echo off
rem ==========================================================================
rem OFGTaskList v1.0 (11-04-2007)
rem
rem DETALLES:
rem
rem Muestra una lista en formato HTML de los procesos en ejecución
rem actualmente en el equipo local. Basado en el comando "TASKLIST.EXE".
rem
rem
rem PROGRAMADO POR:
rem
rem Óscar Fernández González a.k.a. Osc@rNET
rem
rem http://www.ofgsoftware.com (postmaster@ofgsoftware.com)
rem
rem
rem LICENCIA:
rem
rem El modelo de desarrollo que sigue este programa es de "Software Libre".
rem Puede ser usado, copiado, estudiado, modificado y redistribuido
rem libremente.
rem
rem Si haces alguna modificación o mejora, agradecería de tu parte que
rem me la mandases e hicieras una mención sobre el origen del código,
rem citando mí nombre y sitio Web, aunque no estás obligado a ello.
rem
rem
rem SOPORTE:
rem
rem Osc@rNET no ofrece ningún tipo de soporte sobre este Software; se
rem suministra "TAL CUAL" y sin garantías de ninguna especie.
rem
rem ==========================================================================
rem --------------------------------------------------------------------------
rem DEFINICION DE VARIABLES
rem --------------------------------------------------------------------------
setlocal
set _Opcion=
set _HTMLFile=%TEMP%\%RANDOM%.html
set _TaskList=%windir%\system32\tasklist.exe
set _IE=%ProgramFiles%\Internet Explorer\iexplore.exe
set _MF=%ProgramFiles%\Mozilla FireFox\firefox.exe
set _NE=%ProgramFiles%\Netscape\Netscape\Netscp.exe
set _ProgramName=OFGTaskList
set _ProgramVersion=v1.0 (11-04-2007)
set _ProgramLicense=[Software Libre]
set _ProgramCopyright=Programado por Osc@rNET - http://www.ofgsoftware.com
set _ProgramTitle=%_ProgramName% %_ProgramVersion% %_ProgramLicense%
rem --------------------------------------------------------------------------
rem INICIO
rem --------------------------------------------------------------------------
:Inicio
color 17
cls
echo %_ProgramTitle%
echo %_ProgramCopyright%
echo.
echo Muestra una lista en formato HTML de los procesos en ejecución actualmente
echo en el equipo local. Basado en el comando "TASKLIST.EXE".
echo ________________________________________________________________________________
rem --------------------------------------------------------------------------
rem COMPROBAR CREACION DE ARCHIVO TEMPORAL HTML
rem --------------------------------------------------------------------------
:Comprobar_HTMLFile
echo OK > %_HTMLFile%
del %_HTMLFile% > nul
if not exist %_HTMLFile% goto Comprobar_HTMLFile_FIN
echo ERROR: ¡Ejecución abortada¡
echo.
echo ¡No se puede crear el archivo temporal "%_HTMLFile%"!
echo.
echo.
echo.
echo PULSE UNA TECLA PARA SALIR...
pause > nul
goto FIN
:Comprobar_HTMLFile_FIN
rem --------------------------------------------------------------------------
rem COMPROBAR COMANDO "TASKLIST.EXE"
rem --------------------------------------------------------------------------
:Comprobar_TaskList
if exist "%_TaskList%" goto Comprobar_TaskList_FIN
echo ERROR: ¡Ejecución abortada¡
echo.
echo ¡No existe el comando "%_TaskList%" en el sistema!
echo.
echo.
echo.
echo PULSE UNA TECLA PARA SALIR...
pause > nul
goto FIN
:Comprobar_TaskList_FIN
rem --------------------------------------------------------------------------
rem COMPROBAR NAVEGADORES DISPONIBLES EN EL SISTEMA
rem --------------------------------------------------------------------------
:Comprobar_Navegadores
if exist "%_IE%" (set _HTMLViewer=%_IE%) & (goto Comprobar_Navegadores_FIN)
if exist "%_MF%" (set _HTMLViewer=%_MF%) & (goto Comprobar_Navegadores_FIN)
if exist "%_NE%" (set _HTMLViewer=%_NE%) & (goto Comprobar_Navegadores_FIN)
echo ERROR: ¡Ejecución abortada¡
echo.
echo ¡No existe un navegador de internet compatible en el sistema!
echo.
echo ^* Internet Explorer (no existe):
echo %_IE%
echo.
echo ^* Mozilla FireFox (no existe):
echo %_MF%
echo.
echo ^* Netscape (no existe):
echo %_NE%
echo.
echo.
echo.
echo PULSE UNA TECLA PARA SALIR...
pause > nul
goto FIN
:Comprobar_Navegadores_FIN
rem --------------------------------------------------------------------------
rem MENU GENERAL
rem --------------------------------------------------------------------------
:Menu_General
echo - MENU GENERAL -
echo.
echo [1] Informe sobre Procesos (simple).
echo [2] Informe sobre Procesos (detallado).
echo [3] Informe sobre Servicios.
echo [4] Informe sobre Módulos.
echo [5] Todos los informes (1, 2, 3 y 4).
echo [6] Salir.
echo.
set /p _Opcion= Selecciona una opción:
if "%_Opcion%"=="1" goto Generar_Informe
if "%_Opcion%"=="2" goto Generar_Informe
if "%_Opcion%"=="3" goto Generar_Informe
if "%_Opcion%"=="4" goto Generar_Informe
if "%_Opcion%"=="5" goto Generar_Informe
if "%_Opcion%"=="6" goto FIN
goto Inicio
rem --------------------------------------------------------------------------
rem GENERAR INFORME
rem --------------------------------------------------------------------------
:Generar_Informe
echo ________________________________________________________________________________
echo Generando informe. Espere un momento, por favor...
echo.
set _RETURN=:Volver_HTML_Head
goto HTML_Head
:Volver_HTML_Head
echo ^<body^> >> %_HTMLFile%
echo ^<div align="center" class="titulo"^>%_ProgramTitle%^</div^> >> %_HTMLFile%
echo ^<div align="center" class="subtitulo"^>Programado por ^Óscar Fern^ández Gonz^ález a.k.a. Osc@rNET^</div^> >> %_HTMLFile%
echo ^<div align="center" class="subtitulo"^>^<a href="http://www.ofgsoftware.com" target="_blank"^>http://www.ofgsoftware.com^</a^>^</div^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
if "%_Opcion%"=="1" goto Informe1
if "%_Opcion%"=="2" goto Informe2
if "%_Opcion%"=="3" goto Informe3
if "%_Opcion%"=="4" goto Informe4
rem --------------------------------------------------------------------------
:Informe1
echo ^<div align="center" class="subtitulo"^>^<u^>INFORME SOBRE PROCESOS (Simple)^</u^>^</div^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<table align="center" border="0" bgcolor="#949E9C" cellpadding="0" cellspacing="1"^> >> %_HTMLFile%
echo ^<tr bgcolor="#CCCCCC"^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE DE IMAGEN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>P.I.D.^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE^<br /^>DE SESI^ÓN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NRO. DE^<br /^>SESI^ÓN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>USO DE^<br /^>MEMORIA^</strong^>^</td^> >> %_HTMLFile%
echo ^</tr^> >> %_HTMLFile%
for /f "usebackq tokens=*" %%A in (`tasklist /fo csv /nh ^| sort`) do ((
echo ^<tr bgcolor="#EBEBEB"^> >> %_HTMLFile%) & (
for /f "tokens=1 delims=," %%B in ("%%A") do (
echo ^<td align="left" nowrap="nowrap"^>%%~B^</td^> >> %_HTMLFile%
) & (
for /f "tokens=2 delims=," %%C in ("%%A") do (
echo ^<td align="right" nowrap="nowrap"^>%%~C^</td^> >> %_HTMLFile%
) & (
for /f "tokens=3 delims=," %%D in ("%%A") do (
echo ^<td align="center" nowrap="nowrap"^>%%~D^</td^> >> %_HTMLFile%
) & (
for /f "tokens=4 delims=," %%E in ("%%A") do (
echo ^<td align="center" nowrap="nowrap"^>%%~E^</td^> >> %_HTMLFile%
) & (
for /f "tokens=5 delims=," %%F in ("%%A") do (
echo ^<td align="right" nowrap="nowrap"^>%%~F^</td^> >> %_HTMLFile%
) & (
echo ^</tr^> >> %_HTMLFile%))))))
)
echo ^</table^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
if not "%_Opcion%"=="5" goto Fin_Informe
rem --------------------------------------------------------------------------
:Informe2
echo ^<div align="center" class="subtitulo"^>^<u^>INFORME SOBRE PROCESOS (Detallado)^</u^>^</div^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<table align="center" border="0" bgcolor="#949E9C" cellpadding="0" cellspacing="1"^> >> %_HTMLFile%
echo ^<tr bgcolor="#CCCCCC"^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE DE IMAGEN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>P.I.D.^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE^<br /^>DE SESI^ÓN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NRO. DE^<br /^>SESI^ÓN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>USO DE^<br /^>MEMORIA^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>ESTADO^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE DE USUARIO^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>TIEMPO^<br /^>DE C.P.U.^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>T^ÍTULO DE LA VENTANA^</strong^>^</td^> >> %_HTMLFile%
echo ^</tr^> >> %_HTMLFile%
for /f "usebackq tokens=*" %%A in (`tasklist /fo csv /nh /v ^| sort`) do ((
echo ^<tr bgcolor="#EBEBEB"^> >> %_HTMLFile%) & (
for /f "tokens=1 delims=," %%B in ("%%A") do (
echo ^<td align="left" nowrap="nowrap"^>%%~B^</td^> >> %_HTMLFile%
) & (
for /f "tokens=2 delims=," %%C in ("%%A") do (
echo ^<td align="right" nowrap="nowrap"^>%%~C^</td^> >> %_HTMLFile%
) & (
for /f "tokens=3 delims=," %%D in ("%%A") do (
echo ^<td align="center" nowrap="nowrap"^>%%~D^</td^> >> %_HTMLFile%
) & (
for /f "tokens=4 delims=," %%E in ("%%A") do (
echo ^<td align="center" nowrap="nowrap"^>%%~E^</td^> >> %_HTMLFile%
) & (
for /f "tokens=5 delims=," %%F in ("%%A") do (
echo ^<td align="right" nowrap="nowrap"^>%%~F^</td^> >> %_HTMLFile%
) & (
for /f "tokens=6 delims=," %%G in ("%%A") do (
echo ^<td align="center" nowrap="nowrap"^>%%~G^</td^> >> %_HTMLFile%
) & (
for /f "tokens=7 delims=," %%H in ("%%A") do (
echo ^<td align="left" nowrap="nowrap"^>%%~H^</td^> >> %_HTMLFile%
) & (
for /f "tokens=8 delims=," %%I in ("%%A") do (
echo ^<td align="right" nowrap="nowrap"^>%%~I^</td^> >> %_HTMLFile%
) & (
for /f "tokens=9 delims=," %%J in ("%%A") do (
echo ^<td align="left" nowrap="nowrap"^>%%~J^</td^> >> %_HTMLFile%
) & (
echo ^</tr^> >> %_HTMLFile%))))))))))
)
echo ^</table^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
if not "%_Opcion%"=="5" goto Fin_Informe
rem --------------------------------------------------------------------------
:Informe3
echo ^<div align="center" class="subtitulo"^>^<u^>INFORME SOBRE SERVICIOS^</u^>^</div^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<table align="center" border="0" bgcolor="#949E9C" cellpadding="0" cellspacing="1"^> >> %_HTMLFile%
echo ^<tr bgcolor="#CCCCCC"^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE DE IMAGEN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>P.I.D.^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>SERVICIOS^</strong^>^</td^> >> %_HTMLFile%
echo ^</tr^> >> %_HTMLFile%
for /f "usebackq tokens=*" %%A in (`tasklist /fo csv /svc /nh ^| sort`) do ((
echo ^<tr bgcolor="#EBEBEB"^> >> %_HTMLFile%) & (
for /f "tokens=1 delims=," %%B in ("%%A") do (
echo ^<td align="left" valign="top" nowrap="nowrap"^>%%~B^</td^> >> %_HTMLFile%
) & (
for /f "tokens=2* delims=," %%C in ("%%A") do (
echo ^<td align="right" valign="top" nowrap="nowrap"^>%%~C^</td^> >> %_HTMLFile%
) & (
echo ^<td align="left" valign="top" nowrap="nowrap"^> >> %_HTMLFile%) & (
for /f "tokens=1-20,21* delims=," %%E in ("%%~D") do (
(echo %%E^<br /^> >> %_HTMLFile%) & (
if not "%%F"=="" echo %%F^<br /^> >> %_HTMLFile%) & (
if not "%%G"=="" echo %%G^<br /^> >> %_HTMLFile%) & (
if not "%%H"=="" echo %%H^<br /^> >> %_HTMLFile%) & (
if not "%%I"=="" echo %%I^<br /^> >> %_HTMLFile%) & (
if not "%%J"=="" echo %%J^<br /^> >> %_HTMLFile%) & (
if not "%%K"=="" echo %%K^<br /^> >> %_HTMLFile%) & (
if not "%%L"=="" echo %%L^<br /^> >> %_HTMLFile%) & (
if not "%%M"=="" echo %%M^<br /^> >> %_HTMLFile%) & (
if not "%%N"=="" echo %%N^<br /^> >> %_HTMLFile%) & (
if not "%%O"=="" echo %%O^<br /^> >> %_HTMLFile%) & (
if not "%%P"=="" echo %%P^<br /^> >> %_HTMLFile%) & (
if not "%%Q"=="" echo %%Q^<br /^> >> %_HTMLFile%) & (
if not "%%R"=="" echo %%R^<br /^> >> %_HTMLFile%) & (
if not "%%S"=="" echo %%S^<br /^> >> %_HTMLFile%) & (
if not "%%T"=="" echo %%T^<br /^> >> %_HTMLFile%) & (
if not "%%U"=="" echo %%U^<br /^> >> %_HTMLFile%) & (
if not "%%V"=="" echo %%V^<br /^> >> %_HTMLFile%) & (
if not "%%W"=="" echo %%W^<br /^> >> %_HTMLFile%) & (
if not "%%X"=="" echo %%X^<br /^> >> %_HTMLFile%) & (
if not "%%Y"=="" echo %%Y^<br /^> >> %_HTMLFile%) & (
if not "%%Z"=="" echo %%Z^<br /^> >> %_HTMLFile%
))) & (
echo ^</td^> >> %_HTMLFile%
) & (
echo ^</tr^> >> %_HTMLFile%))))
)
echo ^</table^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
if not "%_Opcion%"=="5" goto Fin_Informe
rem -------------------------------------------------------------------------
:Informe4
echo ^<div align="center" class="subtitulo"^>^<u^>INFORME SOBRE M^ÓDULOS^</u^>^</div^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<table align="center" border="0" bgcolor="#949E9C" cellpadding="0" cellspacing="1"^> >> %_HTMLFile%
echo ^<tr bgcolor="#CCCCCC"^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>NOMBRE DE IMAGEN^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>P.I.D.^</strong^>^</td^> >> %_HTMLFile%
echo ^<td align="center" nowrap="nowrap"^>^<strong^>M^ÓDULOS^</strong^>^</td^> >> %_HTMLFile%
echo ^</tr^> >> %_HTMLFile%
for /f "usebackq tokens=*" %%A in (`tasklist /fo csv /m /nh ^| sort`) do ((
echo ^<tr bgcolor="#EBEBEB"^> >> %_HTMLFile%) & (
for /f "tokens=1 delims=," %%B in ("%%A") do (
echo ^<td align="left" valign="top" nowrap="nowrap"^>%%~B^</td^> >> %_HTMLFile%
) & (
for /f "tokens=2* delims=," %%C in ("%%A") do (
echo ^<td align="right" valign="top" nowrap="nowrap"^>%%~C^</td^> >> %_HTMLFile%
) & (
echo ^<td align="left" valign="top" nowrap="nowrap"^> >> %_HTMLFile%) & (
for /f "tokens=1-22 delims=," %%E in ("%%~D") do (
(echo %%E >> %_HTMLFile%) & (
if not "%%F"=="" echo , %%F >> %_HTMLFile%) & (
if not "%%G"=="" echo , %%G >> %_HTMLFile%) & (
if not "%%H"=="" echo , %%H >> %_HTMLFile%) & (
if not "%%I"=="" echo , %%I ^<br /^> >> %_HTMLFile%) & (
if not "%%J"=="" echo %%J >> %_HTMLFile%) & (
if not "%%K"=="" echo , %%K >> %_HTMLFile%) & (
if not "%%L"=="" echo , %%L >> %_HTMLFile%) & (
if not "%%M"=="" echo , %%M >> %_HTMLFile%) & (
if not "%%N"=="" echo , %%N ^<br /^> >> %_HTMLFile%) & (
if not "%%O"=="" echo %%O >> %_HTMLFile%) & (
if not "%%P"=="" echo , %%P >> %_HTMLFile%) & (
if not "%%Q"=="" echo , %%Q >> %_HTMLFile%) & (
if not "%%R"=="" echo , %%R >> %_HTMLFile%) & (
if not "%%S"=="" echo , %%S ^<br /^> >> %_HTMLFile%) & (
if not "%%T"=="" echo %%T >> %_HTMLFile%) & (
if not "%%U"=="" echo , %%U >> %_HTMLFile%) & (
if not "%%V"=="" echo , %%V >> %_HTMLFile%) & (
if not "%%W"=="" echo , %%W >> %_HTMLFile%) & (
if not "%%X"=="" echo , %%X^<br /^> >> %_HTMLFile%) & (
if not "%%Y"=="" echo %%Y >> %_HTMLFile%) & (
if not "%%Z"=="" echo , %%Z , [...]>> %_HTMLFile%
))) & (
echo ^</td^> >> %_HTMLFile%
) & (
echo ^</tr^> >> %_HTMLFile%))))
)
echo ^</table^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
echo ^<br /^> >> %_HTMLFile%
rem --------------------------------------------------------------------------
:Fin_Informe
echo ^<div align="center" class="detalle"^>^<i^>^*Informe generado en la computadora "%COMPUTERNAME%" por el usuario "%USERDOMAIN%\%USERNAME%" a las %TIME% del %DATE%^</i^>^</div^> >> %_HTMLFile%
echo ^</body^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^</html^> >> %_HTMLFile%
echo ¡Informe generado correctamente!.
echo.
echo NOTA: Para regresar al menú cierre la ventana del informe (navegador).
"%_HTMLViewer%" %_HTMLFile%
del %_HTMLFile% > nul
goto Inicio
rem --------------------------------------------------------------------------
rem IMPRIMIR CABECERA HTML
rem --------------------------------------------------------------------------
:HTML_Head
echo ^<!DOCTYPE html > %_HTMLFile%
echo PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" >> %_HTMLFile%
echo "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^<html xmlns="http://www.w3.org/1999/xhtml"^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^<head^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^<title^>%_ProgramTitle%^</title^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" /^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^<style type="text/css"^> >> %_HTMLFile%
echo ^<!-- >> %_HTMLFile%
echo body { >> %_HTMLFile%
echo background-color: #ECE9D8; >> %_HTMLFile%
echo margin: 20px; >> %_HTMLFile%
echo font-family: Verdana, Arial, Helvetica, sans-serif; >> %_HTMLFile%
echo font-size: 11px; >> %_HTMLFile%
echo color: #185184; >> %_HTMLFile%
echo } >> %_HTMLFile%
echo. >> %_HTMLFile%
echo td { >> %_HTMLFile%
echo padding: 5px; >> %_HTMLFile%
echo } >> %_HTMLFile%
echo. >> %_HTMLFile%
echo .titulo { >> %_HTMLFile%
echo font-family: Verdana, Arial, Helvetica, sans-serif; >> %_HTMLFile%
echo font-size: 16px; >> %_HTMLFile%
echo font-weight: bold; >> %_HTMLFile%
echo color: #0046D5; >> %_HTMLFile%
echo } >> %_HTMLFile%
echo. >> %_HTMLFile%
echo .subtitulo { >> %_HTMLFile%
echo font-family: Verdana, Arial, Helvetica, sans-serif; >> %_HTMLFile%
echo font-size: 12px; >> %_HTMLFile%
echo font-style: italic; >> %_HTMLFile%
echo font-weight: bold; >> %_HTMLFile%
echo color: #0046D5; >> %_HTMLFile%
echo } >> %_HTMLFile%
echo. >> %_HTMLFile%
echo .detalle { >> %_HTMLFile%
echo font-family: Verdana, Arial, Helvetica, sans-serif; >> %_HTMLFile%
echo font-size: 10px; >> %_HTMLFile%
echo color: #185184; >> %_HTMLFile%
echo } >> %_HTMLFile%
echo ^--^> >> %_HTMLFile%
echo ^</style^> >> %_HTMLFile%
echo. >> %_HTMLFile%
echo ^</head^> >> %_HTMLFile%
echo. >> %_HTMLFile%
goto %_RETURN%
rem --------------------------------------------------------------------------
rem FIN
rem --------------------------------------------------------------------------
:FIN
endlocal
color
cls